.bat批处理文件实现进程守护

手头有个Windows下的第三方程序负责提供httpapi，但总是卡死无响应导致服务停摆，又没办法人工一直盯着看，自带的程序守护无法解决问题，因为程序并没有闪退。

那只能想个办法，在程序卡死时重启进程来恢复服务，因为对Windows程序守护这方面确实不懂，经过各路搜索之后，觉得用bat批处理对我来说最简单

::参考https://www.cnblogs.com/mq0036/p/12133516.html
@echo off
chcp 65001
::清屏
cls
::设置title
title processWatch
::日期 时间
set d=%date:~0%
@REM set time=%time:~0,8%
::log路径
set logFile=.\log.txt
::等待秒
set _interval=10
::执行软件路径
set runAppPath="D:\Program Files (x86)\WinSCP\WinSCP.exe"
if '%runAppPath%'=='' (goto end)

for %%a in (%runAppPath%) do (
set _processName=%%~na
set _processNameExt=%%~nxa
set runAppFolder=%%~dpa

echo ********守护开启%time:~0,8%******** >> %logFile%
)

@REM echo 程序名：%_processName%
@REM echo 程序名含后缀：%_processNameExt%
@REM echo 执行文件目录：%runAppFolder%
@REM echo 完整执行文件路径：%runAppPath%
@REM echo ====================================================
goto checkstart


:checkstart

for /f "tokens=1" %%n in ('tasklist.exe ^| find /I "%_processNameExt%" ') do ( 
if '%%n'=='%_processNameExt%' (goto checkend) )
echo 检查进程【%_processNameExt%】未在运行

:startApp
echo [%d% %time:~0,8%] 未检测到【%_processNameExt%】的进程，将重新启动程序 >> %logFile%
echo [%d% %time:~0,8%] 重新启动程序：%runAppPath%
echo [%d% %time:~0,8%] 重新启动程序：%runAppPath% >> %logFile%
echo 开始执行 start "" %runAppPath%
pushd %runAppFolder%
start "" %runAppPath%
popd
echo, >> %logFile%


:checkend
echo [%d% %time:~0,8%] 程序【%_processNameExt%】运行正常,%_interval%秒后继续检查......
choice /t %_interval% /d y /n >nul
goto checkstart

:end
echo end.

如果不需要日志的话，有个简化版

::参考https://blog.csdn.net/u010182162/article/details/109336953
@echo off
::设置utf-8编码
chcp 65001
title processWatch
cls
::设置待执行软件完整路径
set runAppPath="D:\Program Files (x86)\WinSCP\WinSCP.exe"
::设置时间间隔，单位：秒
set _interval=3
::自赋值参数
set runAppFolder=''
set _processName=''
set _processNameExt=''
if '%runAppPath%'=='' (goto end)

for %%a in (%runAppPath%) do (
::执行文件的完整目录
set runAppFolder=%%~dpa
::文件名
set _processName=%%~na
::文件名+扩展后缀
set _processNameExt=%%~nxa
)
@REM echo %runAppPath%
@REM echo %runAppFolder%
@REM echo %_processName%
@REM echo %_processNameExt%
echo 现在时间：%date%%time% 
echo ********程序开始启动********
goto checkstart

:checkstart
::检查进程是否还在
for /f "tokens=1" %%n in ('tasklist.exe ^| find /I "%_processNameExt%" ') do ( 
if '%%n'=='%_processNameExt%' (goto checkend)
)

:startApp
::重新启动进程
::打开目录
pushd %runAppFolder%
::输入当前时间和软件路径
echo %date:~0,10% %time:~0,8%: %runAppPath%
::如果程序直接启动
start "" %runAppPath%
::如果程序需要参数，用下面的方法启动
::start %runAppPath% -paramKey=paramValue
popd

:checkend
::延迟N秒后执行检查 
choice /t %_interval% /d y /n >nul
goto checkstart

:end
echo end.

通过进程名来看是否软件掉线，但是对于同名称的来说就不适用了，因为软件是提供HTTPAPI的，会监听一个本地ip端口，所以想到用netstat来查找判断程序是否还在正常响应，于是找到了

::参考https://blog.csdn.net/qin9r3y/article/details/22805095
@echo off

::检测时间间隔，单位：秒
set _interval=5

::需要守护的进程名称
set _processName=WinRAR

::需要守护的进程启动命令
set _processCmd=C:\ideavim-0.32.zip

::需要守护的进程预估启动完毕所需时间，单位：秒
set _processTimeout=10

::需要守护的进程所监听的端口
set _port=8080

::进程用户名，一般是Administrator
set _username=Administrator 

:LOOP
set /a isAlive=false

::通过进程名称检测
::tasklist /FI "username eq %_username%" | find /C "%_processName%" > temp.txt
::set /p num= < temp.txt
::del /F temp.txt

::通过进程的端口是否正在被监听检测
netstat -an | find /C "0.0.0.0:%_port%" > temp.txt
set /p num= < temp.txt
del /F temp.txt

if "%num%" == "0" (
start %_processCmd% | echo 启动 %_processName% 于 %time%
choice /D y /t %_processTimeout% > nul
)

if "%num%" NEQ "0" echo 已启动

::ping -n %_interval% 127.1>nul
choice /D y /t %_interval% >nul

goto LOOP

该脚本运行后会出现一个dos窗口，若觉得碍眼可以用记事本将下面保存为扩展名为.vbs的文件。其中guard.bat是上面批处理保存的文件名。两个文件放在同一目录下双击vbs文件后，守护进程就在后台运行了，单这样得通过资源管理器结束cmd进程才能停止守护进程。

set ws=WScript.CreateObject("WScript.Shell")
ws.Run "guard.bat",0